Sonnensegler.de

AND HER DANCING AND HER LAUGHING.

Howto: iTunes unter MacOS die Queue-Funktion von Winamp geben.May 6th, 2009

Wer wie ich seit seinem Umstieg von Windows auf MacOS die tolle Queue-Funktion von Winamp vermisst, bei der man das aktuell ausgewählte Lied (egal wo) per “q”-Taste als nächstes abspielen lassen kann, dem sei nun in Sachen iTunes geholfen.

1.Das Script von itrebax auf macosxhints.com in ein neues Fenster eines Texteditors eurer Wahl reinkopieren:

tell application "iTunes"
if not (exists playlist "Queue") then
set queuePlaylist to (make new user playlist ¬
with properties {name:"Queue", shuffle:false})
else
set queuePlaylist to playlist "Queue"
end if
if current playlist is not queuePlaylist then
set curtrack to (duplicate current track to queuePlaylist)
else
set curtrack to {}
end if
if selection is not {} then
set sel to a reference to selection
duplicate sel to queuePlaylist
end if
if curtrack is not {} then
set playPosition to player position
play curtrack
set player position to playPosition
end if
end tell

Als z.B. queue.scpt (für mehr Infos zu Apple-Scripts siehe auch hier) speichern.

2. In den Ordner ~/Library/iTunes/Scripts reinkopieren. “~” steht hierbei für euren Benutzer-root-Ordner, also normalerweise euer Name (evtl. als Abkürzung). Falls der Ordner “Scripts” noch nicht besteht, erstellt ihn neu.

3.Nun geht ihr in iTunes in eine beliebige selbstzusammengestellte Playlist und startet diese. Oben in der Menüleiste werdet ihr zwischen den Punkten “Fenster” und “Hilfe” das neu hinzugekommene iTunes Script Menu – Symbol, eine ausgerollte Papierrolle bemerkt haben. Wenn ihr es anklickt, seht ihr dort euer Script “queue”. Wenn ihr das anklickt, wird der gerade ausgewählte Song, egal wo er sich befindet, ob in der aktuellen oder einer anderen Playlist, zur Liste “Queue”, die links in der Sidebar bei euren Wiedergabelisten erscheint, hinzugefügt. Daher könnt ihr wild durch die iTunes Bibliothek gehen und mit eurem Keyboard-Shortcut (s.u.) jedes beliebige Lied, soviele nacheinander wie ihr möchtet, zur “Queue” hinzufügen.

4. Schneller als mit dem Symbol (s.o.) geht es mit einem Keyboard-Shortcut. Dazu in die Systemeinstellungen auf “Tastatur und Maus” gehen, ganz unten in der Leiste bei “Tastatur-Kurzbefehle für Programme” mithilfe des “+”-Buttons einen neuen Befehl hinzufügen, als Programm iTunes auswählen, in das Feld für die Bezeichnung “queue” (ohne .scpt!!) schreiben und dem ganzen einen Shortcut eurer Wahl geben, z.B. cmd+alt+#. Testet in iTunes ob der Shortcut nicht schon vergeben ist!

Nun könnt ihr jedes beliebige Lied anwählen und mit eurem Keyboard-Shortcut als nächstes in die Queue setzen.

Info: Wen es stört, dass das Queueing erst funktioniert wenn ein Track läuft und Queueing für iPod-Tracks braucht , der kann auch das erweiterte Script von jediknil verwenden:

tell application "iTunes"
set currentSource to container of view of front browser window
if not (exists playlist " Queue" of currentSource) then
set queuePlaylist to (make new user playlist ¬
with properties {name:" Queue", shuffle:false} at currentSource)
else
set queuePlaylist to playlist " Queue" of currentSource
end if
set curtrack to {}
if player state is not stopped then
if current playlist is not queuePlaylist then
delete tracks of queuePlaylist
set curtrack to (duplicate current track to queuePlaylist)
end if
else
delete tracks of queuePlaylist
end if
if selection is not {} then
set sel to a reference to selection
duplicate sel to queuePlaylist
end if
if curtrack is not {} then
set playPosition to player position
set curState to player state
play curtrack
set player position to playPosition
if curState is paused then pause
else if tracks of queuePlaylist is not {} and (player state is stopped or current playlist is not queuePlaylist) then
play first track of queuePlaylist
end if
end tell

imagepostMay 6th, 2009 imagetime02:07

Leave a Reply

You must be logged in to post a comment.